mirror of
https://github.com/systemd/systemd.git
synced 2026-08-12 22:17:19 +00:00
7a6bf458de
The zsh completion for timedatectl was missing three commands ('show',
'ntp-servers', 'revert') and five options (--monitor, -p/--property=,
-a/--all, --value, -P) that are already present in the bash completion,
documented in the man page, and implemented in the binary.
Fixes #16507
(cherry picked from commit 104750fd60)
(cherry picked from commit 2bb7b1ae7c)
(cherry picked from commit 015e3df921)
94 lines
2.9 KiB
Plaintext
94 lines
2.9 KiB
Plaintext
#compdef timedatectl
|
|
# SPDX-License-Identifier: LGPL-2.1-or-later
|
|
|
|
_timedatectl_set-timezone(){
|
|
local -a _timezones
|
|
_timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
|
|
compadd "$_timezones[@]"
|
|
}
|
|
|
|
_timedatectl_set-time(){
|
|
_message "YYYY-MM-DD HH:MM:SS"
|
|
}
|
|
|
|
_timedatectl_set-local-rtc(){
|
|
local -a _options
|
|
_options=(
|
|
'0:Maintain RTC in universal time'
|
|
'1:Maintain RTC in local time'
|
|
)
|
|
_describe options _options
|
|
}
|
|
|
|
_timedatectl_set-ntp(){
|
|
local -a _options
|
|
_options=(
|
|
'0:Disable NTP based network time configuration'
|
|
'1:Enable NTP based network time configuration'
|
|
)
|
|
_describe options _options
|
|
}
|
|
|
|
_timedatectl_ntp-servers(){
|
|
if (( CURRENT == 2 )); then
|
|
_net_interfaces
|
|
else
|
|
_message "NTP server"
|
|
fi
|
|
}
|
|
|
|
_timedatectl_revert(){
|
|
if (( CURRENT == 2 )); then
|
|
_net_interfaces
|
|
else
|
|
_message "no more options"
|
|
fi
|
|
}
|
|
|
|
_timedatectl_command(){
|
|
local -a _timedatectl_cmds
|
|
_timedatectl_cmds=(
|
|
'status:Show current time settings'
|
|
'show:Show properties of systemd-timedated'
|
|
'set-time:Set system time'
|
|
'set-timezone:Set system timezone'
|
|
'list-timezones:Show known timezones'
|
|
'set-local-rtc:Control whether RTC is in local time'
|
|
'set-ntp:Control whether NTP is enabled'
|
|
'timesync-status:Show status of systemd-timesyncd'
|
|
'show-timesync:Show properties of systemd-timesyncd'
|
|
'ntp-servers:Set the interface specific NTP servers'
|
|
'revert:Revert the interface specific NTP servers'
|
|
)
|
|
if (( CURRENT == 1 )); then
|
|
_describe -t commands 'timedatectl command' _timedatectl_cmds
|
|
else
|
|
local curcontext="$curcontext"
|
|
cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
|
|
if (( $#cmd )); then
|
|
if (( $+functions[_timedatectl_$cmd] )); then
|
|
_timedatectl_$cmd
|
|
else
|
|
_message "no more options"
|
|
fi
|
|
else
|
|
_message "unknown timedatectl command: $words[1]"
|
|
fi
|
|
fi
|
|
}
|
|
|
|
_arguments -s \
|
|
'(- *)'{-h,--help}'[Show this help]' \
|
|
'(- *)--version[Show package version]' \
|
|
'--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
|
|
'--monitor[Monitor status of systemd-timesyncd]' \
|
|
'--no-pager[Do not pipe output into a pager]' \
|
|
'--no-ask-password[Do not prompt for password]' \
|
|
'(-H --host)'{-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
|
|
'(-M --machine)'{-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
|
|
'*'{-p+,--property=}'[Show only properties by this name]:property' \
|
|
'(-a --all)'{-a,--all}'[Show all properties, including empty ones]' \
|
|
'--value[When showing properties, only print the value]' \
|
|
'*-P+[Equivalent to --value --property=]:property' \
|
|
'*::timedatectl commands:_timedatectl_command'
|