mirror of
https://github.com/systemd/systemd.git
synced 2026-07-23 16:00:06 +00:00
c0cc01de8a
Now our baseline of meson is 0.62, hence install_symlink() can be used. Note, install_symlink() implies install_emptydir() for specified install_dir. Hence, this also drops several unnecessary install_emptydir() calls. Note, the function currently does not support 'relative' and 'force' flags, so several 'ln -frsT' inline calls cannot be replaced.
39 lines
1.1 KiB
Meson
39 lines
1.1 KiB
Meson
# SPDX-License-Identifier: LGPL-2.1-or-later
|
|
|
|
if conf.get('HAVE_LIBCRYPTSETUP') != 1
|
|
subdir_done()
|
|
endif
|
|
|
|
subdir('cryptsetup-tokens')
|
|
|
|
systemd_cryptsetup_sources = files(
|
|
'cryptsetup-keyfile.c',
|
|
'cryptsetup.c',
|
|
)
|
|
|
|
if conf.get('HAVE_P11KIT') == 1
|
|
systemd_cryptsetup_sources += files('cryptsetup-pkcs11.c')
|
|
endif
|
|
|
|
executables += [
|
|
executable_template + {
|
|
'name' : 'systemd-cryptsetup',
|
|
'public' : true,
|
|
'sources' : systemd_cryptsetup_sources,
|
|
'dependencies' : [
|
|
libcryptsetup,
|
|
libopenssl,
|
|
libp11kit_cflags,
|
|
],
|
|
},
|
|
generator_template + {
|
|
'name' : 'systemd-cryptsetup-generator',
|
|
'sources' : files('cryptsetup-generator.c'),
|
|
},
|
|
]
|
|
|
|
# symlink for backwards compatibility after rename
|
|
install_symlink('systemd-cryptsetup',
|
|
pointing_to : libexecdir_to_bin / 'systemd-cryptsetup',
|
|
install_dir : libexecdir)
|